on right click on ender chest:
	cancel event
	set {_before} to block data of event-block
	set event-block to air
	spawn block display of ender chest at event-block:
		set transformation translation of display to vector from 0.5, -0.5, -0.5
		set right transformation rotation of display to right transformation rotation of display rotated around the y-axis by -1.57
		set {_display} to event-entity
	set {_mod} to 0.04
	add a diamond, gold ingot, emerald, stone, bedrock, diamond sword, wooden hoe, any ore, any weapon, any armour and any wood to {_items::*}
	play sound "BLOCK_CHEST_OPEN" at event-block
	loop line from event-block to location 1.6 blocks above event-block with density 10:
		teleport {_display} to loop-value
		wait a tick
	loop circle at location 1.6 blocks above event-block with radius 2 and density 4.5:
		add loop-value to {_locations::*}
		teleport {_display} to loop-value
		set {_quaternion} to left transformation rotation of {_display}
		set {_quaternion} to {_quaternion} rotated around the z-axis by {_mod}
		set {_quaternion} to {_quaternion} rotated around the x-axis by {_mod}
		add {_quaternion} to {_quaternions::*}
		set left transformation rotation of {_display} to {_quaternion}
		add 1 to {_count}
		if {_count} is greater than 20:
			{_count} is less than 100
			drop a random item out of {_items::*} at location 1.5 blocks below loop-value without velocity
			play sound "ENTITY_EXPERIENCE_ORB_PICKUP" with volume 0.5 at loop-value
		wait a tick
	set {_mod} to 0.1
	set {_index} to size of {_locations::*}
	loop {_locations::*}:
		teleport {_display} to loop-value
		subtract 1 from {_index}
		set left transformation rotation of {_display} to {_quaternions::%{_index}%}
		wait a tick
	loop line from location 1.6 blocks above event-block to event-block with density 10:
		teleport {_display} to loop-value
		wait a tick
	play sound "BLOCK_CHEST_CLOSE" at event-block
	clear all entities
	set event-block to {_before}